my fancy 'kitchen' button

[MikeB]

In our home, we have a large great room above our garage (our 'theater' room) where we typically entertain and watch movies/sports. The room has a large opening with a flight of stairs that lead down into our kitchen.

 

We wanted to have an easy way to turn our main kitchen lights on or off from the great room. So, I setup one of our great room KPL's secondary buttons to control our main kitchen lights (I made it a controller in my KitchenMain scene).

 

This worked great, but we often found times when we left a light on in the kitchen OTHER than the main lights, say the table or bar light, but wanted the ability to turn it off from the great room.

 

The KPL secondary button is called 'TheaterControls1B'. I made it a responder in a 'status' scene called 'KitchenTheaterStatus'. Also, as I mentioned above, it is a controller of our 'KitchenMain' scene.

 

I created the following programs to add the desired functionality:

 

If
       Status  'TheaterControls1B' is Off
   And (
            Status  'KitchenBar1' is not Off
         Or Status  'KitchenMain1' is not Off
         Or Status  'KitchenSink1' is not Off
         Or Status  'KitchenTable1' is not Off
       )

Then
       Wait  2 seconds
       Set Scene 'KitchenTheaterStatus' On

Else
  - No Actions - (To add one, press 'Action')

 

The above program checks to see if any of my kitchen lights are on. If they are on, it turns my great room's KPL secondary 'kitchen' button ON.

 

 

If
       Status  'TheaterControls1B' is not Off
   And (
            Status  'KitchenBar1' is Off
        And Status  'KitchenMain1' is Off
        And Status  'KitchenSink1' is Off
        And Status  'KitchenTable1' is Off
       )

Then
       Wait  2 seconds
       Set Scene 'KitchenTheaterStatus' Off

Else
  - No Actions - (To add one, press 'Action')

 

The above program checks to see if all of my kitchen lights are off. If they are off, it turns my great room's KPL secondary 'kitchen' button OFF.

 

 

If
            Control 'TheaterControls1B' is switched Off
   And (
            Status  'KitchenBar1' is not Off
         Or Status  'KitchenSink1' is not Off
         Or Status  'KitchenTable1' is not Off
       )

Then
       Set Scene 'KitchenAll' Off

Else
  - No Actions - (To add one, press 'Action')

 

The above program triggers when I press our KPL secondary 'Kitchen' button off. It checks to see if any of my secondary kitchen lights are on, and if they are it turns them all off.

 

 

So, my final functionality is this:

- my KPL secondary button is lit if ANY of my kitchen lights are left on

- my KPL secondary button automatically turns off if ALL of my kitchen lights are off

- if ALL kitchen lights are off, and I press the button, it turns my main kitchen lights ON

- if ANY kitchen lights are on, and I press the button, it turns them all OFF

 

Hope this helps someone who might be looking to do something similar.