Safety for all off type scenes

[beernutmark]

Hi all,

New member and loving my ISY. One thing I couldn't find in any searches of the forum was how to make a "safety" for all off scenes. I love being able to turn off all the lights (or groups of lights) with a single switch but we have already had problems with accidentally turning off the lights on people when not desired.

 

Here is my solution. Perhaps there are better solutions. The following program only enables the all off scene if the button is pressed three times within 2 seconds. The switches are set to toggle-off mode.

 

Hopefully this will help someone else out or maybe someone can suggest an even cleaner way to accomplish this.

 

All Off Button Click

If
       Control 'Main Level / Front Entry Controller - D' is switched Off
    Or Control 'Basement / Garage Entry Controller - D' is switched Off

Then
       Run Program 'All Off Check' (If)
       Wait  2 seconds
       $i.AllOff.Check  = 0
       Run Program 'All Lights update LED' (If)

Else
  - No Actions - (To add one, press 'Action')

 

All Off Check (Important to uncheck Enabled to prevent running arbitrarily)

If
       $i.AllOff.Check >= 2

Then
       Set Scene 'Lights Off Scenes / All Off' On
       $i.AllOff.Check  = 0

Else
       $i.AllOff.Check += 1

 

All Lights Update LED

If
       Program 'Any Lights On' is True

Then
       Wait  2 seconds
       Set Scene 'LED Control Scenes / Any Lights On LED' On

Else
       Wait  7 seconds
       Set Scene 'LED Control Scenes / Any Lights On LED' Off

 

Any Lights On (Note that I have sleep timer programs for my kids room, this program says their lights are on only if their lights are on and the sleep timer is not set)

If
       Status  'Upstairs / Bedroom Hallway East' is not Off
    Or Status  'Upstairs / Bedroom Hallway West' is not Off
    Or (
            Status  'Upstairs / East Bedroom' is not Off
        And $s.Sleep.EastBR is 0
       )
    Or (
            Status  'Upstairs / West Bedroom' is not Off
        And $s.Sleep.WestBR is 0
       )
    Or Status  'Upstairs / Upstairs Bathroom' is not Off
    Or Status  'Upstairs / Master Bedroom' is not Off
    Or Status  'Upstairs / Master Shower' is not Off
    Or Status  'Upstairs / Master Sink' is not Off
    Or Status  'Upstairs / Master Bath Heat Lamp' is not Off
    Or Status  'Main Level / Back Door' is not Off
    Or Status  'Basement / Basement Bedroom' is not Off
    Or Status  'Main Level / Dining Room' is not Off
    Or Status  'Main Level / Living Room Fireplace' is not Off
    Or Status  'Main Level / Entry Light' is not Off
    Or Status  'Main Level / Front Entry Controller' is not Off
    Or Status  'Main Level / Front Porch' is not Off
    Or Status  'Basement / Garage Entry Controller' is not Off
    Or Status  'Basement / N. Bsmt Hall' is not Off
    Or Status  'Basement / S. Bsmt Hall' is not Off
    Or Status  'Main Level / patio door' is not Off
    Or Status  'Main Level / Kitchen / Kitchen Bar' is not Off
    Or Status  'Main Level / Kitchen / Kitchen' is not Off
    Or Status  'Main Level / Kitchen / Kitchen Counter' is not Off
    Or Status  'Main Level / Kitchen / Kitchen Fireplace' is not Off

Then
  - No Actions - (To add one, press 'Action')

Else
  - No Actions - (To add one, press 'Action')

 

Regards,

Mark