Motion, multiple bathroom lights, manual override

[oskrypuch]

I have fiddled with my bathroom motion setup, and have implemented all of these facets ...

 

1) Control two (or more) separate lights or scenes from motion, with a timed OFF

2) Timer restarts/extends while motion detected

3) Allow for an manual override on the brightness when occupied

4) Allow for a manual forced OFF of some lights when occupied

5) Allow for a manual forced OFF of all lights when leaving

6) Minimize the Insteon com traffic

 

I also have three different modes, depending on time of day, whether dark or light, and whether in 'sleep mode', I've only included the 'day' modes for brevity.

 

Motions are fully controlled by the ISY, and set to ON operation only, 30 second timer.

 

The following variables (programs) are used to flag whether the respective doWait programs are running:

 

var BTH mirror wait

var BTH tub wait

 

The following are two of a number of variables (programs) that I use to control execution logic:

 

var dark

var sleeptime

 

 

This logic is easily extensible for any number of lights.

 

 

BTH motion (day)

If
    Control 'master bath / BTH - PIR-Sensor' is switched On
   And Program 'var sleeptime' is False
   And Program 'var dark' is False

Then
       Run Program 'BTH motion mirror 70' (If)
       Run Program 'BTH motion (day) mirror doWait' (Then Path)
       Run Program 'BTH motion tub 80' (If)
       Run Program 'BTH motion (day) tub doWait' (Then Path)

Else
  - No Actions - (To add one, press 'Action')

 

BTH motion mirror 70 [disabled]

If
       Status  'master bath / BTH - mirror lights' is Off
   And (
            Program 'var BTH mirror wait' is False
        And Program 'var BTH tub wait' is False
       )

Then
       Set 'master bath / BTH - mirror lights' 70%

Else
  - No Actions - (To add one, press 'Action')

 

BTH motion (day) mirror doWait [disabled]

If
  - No Conditions - (To add one, press 'Schedule' or 'Condition')

Then
       Wait  1 second
       Run Program 'var BTH mirror wait' (Then Path)
       Wait  35 minutes 
       Wait  5 minutes  (Random)
       Set 'master bath / BTH - mirror lights' Off
       Run Program 'var BTH mirror wait' (Else Path)

Else
  - No Actions - (To add one, press 'Action')

 

BTH motion tub 80 [disabled]

If
       Status  'master bath / BTH - Tub Pots' is Off
   And (
            Program 'var BTH tub wait' is False
        And Program 'var BTH mirror wait' is False
       )

Then
       Set 'master bath / BTH - Tub Pots' 80%

Else
  - No Actions - (To add one, press 'Action')

 

BTH motion (day) tub doWait [disabled]

If
  - No Conditions - (To add one, press 'Schedule' or 'Condition')

Then
       Wait  1 second
       Run Program 'var BTH tub wait' (Then Path)
       Wait  35 minutes 
       Wait  5 minutes  (Random)
       Set 'master bath / BTH - Tub Pots' Off
       Run Program 'var BTH tub wait' (Else Path)

Else
  - No Actions - (To add one, press 'Action')

 

BTH motion mirror OFF

If
       Control 'master bath / BTH - mirror lights' is switched Off

Then
       Wait  7 seconds
       Run Program 'var BTH mirror wait' (Else Path)
       Stop program 'BTH motion (day) mirror doWait'
       Stop program 'BTH motion (sleep)  doWait'

Else
  - No Actions - (To add one, press 'Action')

 

BTH motion tub OFF

If
       Control 'master bath / BTH - Tub Pots' is switched Off

Then
       Wait  7 seconds
       Run Program 'var BTH tub wait' (Else Path)
       Stop program 'BTH motion (day) tub doWait'

Else
  - No Actions - (To add one, press 'Action')

 

 

Happy to entertain questions, and delighted for any comments.

 

* Orest

[oberkc]

You are having entirely too much fun with this.

[oskrypuch]

Exactly my goal!!

 

* Orest